Recently there was a discussion on one of the Midrange-L mailing lists where someone wanted to be able to read in a very large amount of data from a web service.

This brought about the discussion of the largest string an RPG program could use was 32k, then 64k (approximately), and now 16mb (with V6R1 and up).

But what if you want to read more than that?  Well, this is something I always wanted to try so I did it.  Instead of using a string as the receiver variable on the QtmhRdStin API I decided to try using a pointer.  The following is what I came up with:

     H DFTACTGRP(*NO) BNDDIR('ERPGSDK')
      ****************************************************************
      * Prototypes                                                   *
      ****************************************************************
      /COPY QCOPYSRC,P.ERPGSDK
      /COPY QCOPYSRC,P.HTTPSTD
      /COPY QCOPYSRC,P.IFSSTD
      /COPY QCOPYSRC,P.STRINGS
      *
     D #RdStinPtr      PR                  ExtProc('QtmhRdStin')
     D  RcvRec                         *   Value
     D  RcvLen                       10I 0 Const
     D  RcvRecLen                    10I 0
     D  WPError                      56
      ****************************************************************
      * Work Variables
      ****************************************************************
     D WPError         DS
     D  EBytesP                      10i 0 INZ(%size(WPError))
     D  EBytesA                      10i 0
     D  EMsgID                        7
     D  EReserverd                    1
     D  EData                        40
      *
      * Data read in from page
     D inContLen       S             10i 0
      *
     D data@           S               *
     D rspLen          S             10i 0
     D fd              S             10i 0
      ****************************************************************
      /free
       #startup();
       inContLen = #st_CtoN(#GetEnv('CONTENT_LENGTH'));
       #writeTemplate('stdhtmlheader.erpg');
       #loadTemplate('readbig.erpg':'top');
       #replaceData('/%length%/':%char(inContLen));
       #writeSection();

       if (inContLen > 0);
         data@ = %alloc(inContLen);

         if (data@ <> *null);
           exsr $WriteToStmf;
           dealloc data@;
         endif;

       endif;
       #cleanup();

       *INLR = *on;
       //-------------------------------------------------------------/
       // Write Standard Input to Stream File                         /
       //-------------------------------------------------------------/
       begsr $WriteToStmf;

         #RdStinPtr(data@:inContLen:rspLen:WPError);

         if (rspLen > 0);

           fd = #openStmf('/tmp/bigposttest.txt':1);

           if (fd >= 0);
             #writeStmf(fd:data@:rspLen);
             #closeStmf(fd);
           endif;

         endif;

       endsr;
      /end-free

Now, I'm using our eRPG SDK here to make things a little easier.  But the process is quite simple...

1. Get the Content Length of the request.  This should be available as an Environment Variable named CONTENT_LENGTH and represent the size of the data in the POST made to the server.
2. If this is larger than zero, use the %alloc BIF to allocate the space needed using a pointer in your program. 
3. Use the pointer from step 2 as the receiver for the QtmhRdStin API.
4. Now that you have a pointer to your data, you can manipulate it or, as I did, write it all to a stream file

This application also does return a response to the requesting application with the length of the data received.  The very simple template for that is as follows:

/$top
Content-Length: /%length%/

How I made the request use using our GETURI application to perform at HTTP request as follows:

GETURI URI('myserver/cgi-bin/readbig') DATA(*STMF) DSTMF('/tmp/test.txt') METHOD(*POST)

The file used was about 2mb just for the test.  This was also running on a V5R4 machine so the maximum size of a string is 64k.

This is nothing new, and with newer OS versions isn't really that necessary unless the data you plan on reading from a web application is larger than 16mb, but it was a fun exercise that I've wanted to try for quite some time, and finally made the time for.