bvstone

Calculating the Size of a File Before Base64 Encoding

Posted:

Calculating the Size of a File Before Base64 Encoding

Working with a lot of RESTful APIs and interfaces that perform functions, such as working with Calendars to delivering email (with Google, Office 365, etc), I have found that a lot of data needs to be Base64 Encoded or decoded. 

But, along with this need, there are also some size limits to objects that can be used with these interfaces.  For example, email attachments or entire MIME messages have size limits in place and can differ from API to API.  And that limit normally applies to the data after it has been Base64 encoded, not before.

So, in these cases we can use a very easy function to figure out what the size of a file, or group of data, will be once it is Base64 encoded.

 /COPY QCOPYSRC,APR_B64_H
D stmfSize        S             10i 0
D maxMIMESize     S             10i 0

stmfSize = #getStmfSize(in_sendMailMimeFile);
b64StmfSize = apr_base64_encode_len(stmfSize);

if (b64StmfSize > MAX_SIZE);
  //error
endif;

In this example we first get the size of a stream file that will need to be Base64 Encoded (easily done with the stat() or stat64() APIs available on the IBM i).

Next, we use the apr_base64_encode_len() API, simply passing in the size of the file to be encoded and returned to us will be the size of the file if it were to be Base64 encoded (without actually doing the encoding).  With this information we can then test the size against the maximum size available BEFORE we actually encode it, possibly saving a lot of processing time.

These Base64 functions are available to us from the IBM port of the Apache Base64 Runtime environment.

The /copy member for APR_B64_H can be found online in a few places, like the RPG Next Gen website, but I have also included it here:

 /if defined(APR_BASE64_H)
 /eof
 /endif
 /define APR_BASE64_H
 
  // APR_B64_H --  Include file with definitions for the Base64 routines
  //               included with the Apache Portable Runtime (APR)
  //
  //               On IBM i, this is shipped in the QSYSDIR/QAXIS10HT
  //               service program, which is part of 57xx-SS1 option 3
  //               (57xx-SS1, opt3 = Extended Base Directory Support)
 
  //  APU_DECLARE(int) apr_base64_encode_len(int len);
  //  APU_DECLARE(int) apr_base64_encode(char * coded_dst, const char *plain_src,
  //                                   int len_plain_src);
  //  APU_DECLARE(int) apr_base64_encode_binary(char * coded_dst,
  //                                          const unsigned char *plain_src,
  //                                          int len_plain_src);
  //  APU_DECLARE(int) apr_base64_decode_len(const char * coded_src);
  //  APU_DECLARE(int) apr_base64_decode(char * plain_dst, const char *coded_src);
  //  APU_DECLARE(int) apr_base64_decode_binary(unsigned char * plain_dst,
  //                                         const char *coded_src);
 
D apr_base64_encode_len...
D                 pr            10i 0 extproc('apr_base64_encode_len')
D  len                          10i 0 value
 
D apr_base64_encode...
D                 pr            10i 0 extproc('apr_base64_encode')
D  encoded_dst               65535a   options(*varsize)
D  plain_src                      *   value options(*string)
D  source_len                   10i 0 value
 
D apr_base64_encode_binary...
D                 pr            10i 0 extproc('apr_base64_encode_binary')
D  coded_dst                 65535a   options(*varsize)
D  plain_src                 65535a   options(*varsize) const
D  source_len                   10i 0 value
 
D apr_base64_encode_binary_ptr...
D                 pr            10i 0 extproc('apr_base64_encode_binary')
D  coded_dst                      *
D  plain_src                      *   const
D  source_len                   10i 0 value
 
D apr_base64_decode_len...
D                 pr            10i 0 extproc('apr_base64_decode_len')
D  source_plain                   *   value options(*string)
 
D apr_base64_decode...
D                 pr            10i 0 extproc('apr_base64_decode')
D  plain_dst                 65535a   options(*varsize)
D  coded_src                      *   value options(*string)
 
D apr_base64_decode_ptr...
D                 pr            10i 0 extproc('apr_base64_decode')
D  plain_dst                      *
D  coded_src                      *   const
 
D apr_base64_decode_binary...
D                 pr            10i 0 extproc('apr_base64_decode_binary')
D  plain_dst                 65535a   options(*varsize)
D  coded_src                      *   value options(*string)
 
D apr_base64_decode_binary_ptr...
D                 pr            10i 0 extproc('apr_base64_decode_binary')
D  plain_dst                      *
D  coded_src                      *   const

 





Reply




Copyright 1983-2024 BVSTools
GreenBoard(v3) Powered by the eRPG SDK, MAILTOOL Plus!, GreenTools for Google Apps, jQuery, jQuery UI, BlockUI, CKEditor and running on the IBM i (AKA AS/400, iSeries, System i).