bvstone

Reading JSON Data from Standard Input With YAJL and RPG

Posted:

Reading JSON Data from Standard Input With YAJL and RPG

If you are ever in a situation where you want to read in JSON from Standard Input (POST) using RPG for parsing, then this example is for you.  

This solution uses:

The main function from the YAJL Toolkit used will be yajl_stdin_load_tree().  This function allows you to read JSON data in from Standard Input (from a POST) very easily, load it into YAJL and start parsing right away.

The RPG code for program YAJLSTDIN is as follows:

**FREE
ctl-opt DFTACTGRP(*NO) ACTGRP('YAJL') BNDDIR('YAJLBVS');

// Imports
/copy qrpglesrc,yajl_h
/copy qcopysrc,p.erpgsdk

// YAJL Variables
dcl-s docNode Like(yajl_val);
dcl-s node Like(yajl_val);
dcl-s val Like(yajl_val);
dcl-s yajl_error varchar(500);

// Work Variables
dcl-s firstName char(256);
dcl-s lastName char(256);
dcl-s errorText char(256);

exsr $Input;
exsr $Output;
exsr $Return;

//***************************************************************
// Read Input
//***************************************************************
BegSr $Input;

  docNode = yajl_stdin_load_tree(*ON:yajl_error);

  if (docNode = *NULL) or (yajl_error <> ' ');
    yajl_tree_free(docNode);
    errorText = 'Error reading JSON data. ' + %trim(yajl_error);
  else;
    val = YAJL_object_find(docNode:'firstName');
    firstName = yajl_get_string(val);

    val = YAJL_object_find(docNode:'lastName');
    lastName = yajl_get_string(val);
  endif;

    yajl_tree_free(docNode);

EndSr;
//***************************************************************
// Write Output using ERPGSDK
//***************************************************************
BegSr $Output;

  #startup();

  #writeTemplate('stdhtmlheader.erpg');
  #loadTemplate('yajlstdin.erpg');

  if (errorText <> ' ');
    #loadSection('error');
    #replaceData('/%errorText%/':errorText);
  else;
    #loadSection('main');
    #replaceData('/%firstName%/':firstName);
    #replaceData('/%lastName%/':lastName);
  endif;

  #writeSection();
  #cleanup();

EndSr;
//***************************************************************
// Return
//***************************************************************
BegSr $Return;

  yajl_genClose();
  *INLR = *ON;
  return;

EndSr;

This program is split into 3 main sections or subprocedures:

  • $Input - Read the JSON posted to the application.  As you can see, the yajl_stdin_load_tree() function is called.  If everything works out, we then parse the data into work  variables we already have defined.  You could of course choose to use any method for this, but for simplicity's sake we will parse the data into predefined variables
  • $Output - This section uses the eRPG SDK to output the response to the application.  It will either report an error, or mirror back the data for firstName and lastName that was entered
  • $Return - This is used to close things up.  

In order to call this function, simply load up Postman and set up the application to make a call to https://www.bvstools.com/cgi-bin/yajlstdin as a POST sending the JSON data as follows (you can use any first name and last name you want):

{"firstName":"PuriPuri",
 "lastName":"Prisoner"}

The Postman application should then return either an error, or report back the values you sent.

You sent the following data:

firstName=PuriPuri
lastName=Prisone

Below I have included an export of the Postman data that you can easily use to import into Postman and run.  Simple copy the JSON below, save it as a .json file on your PC, and use the Import option in Postman.  (Note, if you are still using the old browser app of Postman, download the PC version as the browser version is out of date an unsupported):

{
	"info": {
		"_postman_id": "9a70dfd9-a456-42b7-937d-f93c3ba5c927",
		"name": "bvstools",
		"schema": "https://schema.getpostman.com/json/collection/v2.1.0/collection.json"
	},
	"item": [
		{
			"name": "yajlstdin",
			"request": {
				"method": "POST",
				"header": [
					{
						"key": "Content-Type",
						"name": "Content-Type",
						"value": "application/json",
						"type": "text"
					}
				],
				"body": {
					"mode": "raw",
					"raw": "{\"firstName\":\"PuriPuri\",\n \"lastName\":\"Prisoner\"}"
				},
				"url": {
					"raw": "https://www.bvstools.com/cgi-bin/yajlstdin",
					"protocol": "https",
					"host": [
						"www",
						"bvstools",
						"com"
					],
					"path": [
						"cgi-bin",
						"yajlstdin"
					]
				}
			},
			"response": []
		}
	]
}

 

Feel free to check out the other YAJL articles as well for more detail or building and parsing JSON data using YAJL:

Related Articles:


Last edited 07/12/2019 at 10:58:06



Latest Posts:

Calculating the Size of a File Before Base64 Encoding Calculating the Size of a File Before Base64 Encoding
Posted by August 13, 2022
Programming >> RPG Programming
GreenTools for Microsoft Apps (G4MS) v9.12 Now Includes Function to Send Emails using MIME File GreenTools for Microsoft Apps (G4MS) v9.12 Now Includes Function to Send Emails using MIME File
Posted by August 11, 2022
BVSTools >> BVSTools Announcements >> GreenTools for Microsoft Apps (G4MS) Specific Announcements
GreenTools for Google Apps (G4G) v15.20 Now Supports Shortcuts GreenTools for Google Apps (G4G) v15.20 Now Supports Shortcuts
Posted by August 6, 2022
BVSTools >> BVSTools Announcements >> GreenTools for G Suite (Google Apps) (G4G) Specific Announcements
GreenTools for Microsoft Apps (G4MS) Groups Admin Authority Instructions GreenTools for Microsoft Apps (G4MS) Groups Admin Authority Instructions
Posted by July 26, 2022
BVSTools >> BVSTools Software Discussion >> GreenTools for Microsoft Apps (G4MS) Specific Discussion
GreenTools for Microsoft Apps (G4MS) v9.10 Now Includes OneDrive Functions that Work With Groups/Shared Drives GreenTools for Microsoft Apps (G4MS) v9.10 Now Includes OneDrive Functions that Work With Groups/Shared Drives
Posted by July 19, 2022
BVSTools >> BVSTools Announcements >> GreenTools for Microsoft Apps (G4MS) Specific Announcements
GreenTools for Google Apps (G4G) v15.10 Now Includes Drive Functions that Work With Shared Drives GreenTools for Google Apps (G4G) v15.10 Now Includes Drive Functions that Work With Shared Drives
Posted by July 15, 2022
BVSTools >> BVSTools Announcements >> GreenTools for G Suite (Google Apps) (G4G) Specific Announcements
GreenTools for Microsoft Apps (G4MS) v9.00 Now Offers Functions to Bypass Registration Command and BVSTools Landing Page GreenTools for Microsoft Apps (G4MS) v9.00 Now Offers Functions to Bypass Registration Command and BVSTools Landing Page
Posted by July 4, 2022
BVSTools >> BVSTools Announcements >> GreenTools for Microsoft Apps (G4MS) Specific Announcements
What Objects Should I Omit from Replication to Ensure My License Keys Work on my HA/DR System? What Objects Should I Omit from Replication to Ensure My License Keys Work on my HA/DR System?
Posted by June 27, 2022
BVSTools >> BVSTools Software Discussion
GreenTools for Google Apps (G4G) v15.00 Now Offers Functions to Bypass Registration Command and BVSTools Landing Page GreenTools for Google Apps (G4G) v15.00 Now Offers Functions to Bypass Registration Command and BVSTools Landing Page
Posted by May 3, 2022
BVSTools >> BVSTools Announcements >> GreenTools for G Suite (Google Apps) (G4G) Specific Announcements
How Do I Switch From MAILTOOL Plus to GreenTools for Google or Microsoft Office 365? How Do I Switch From MAILTOOL Plus to GreenTools for Google or Microsoft Office 365?
Posted by April 18, 2022
BVSTools >> BVSTools Software Discussion >> Email Tools (MAILTOOL) Specific Discussion
PTFs Issued for SSL/TLS Issues PTFs Issued for SSL/TLS Issues
Posted by March 12, 2022
IBM Power Systems >> PTF Watch
Google Dropping Support for Google Dropping Support for "Less Secure Apps" May 30th, 2022. What Does This Mean for Your IBM i Email?
Posted by March 4, 2022
BVSTools >> BVSTools Software Discussion >> Email Tools (MAILTOOL) Specific Discussion
Have You Installed a New Version of MAILTOOL and Now Things Are Acting Different?  Check the Command Defaults! Have You Installed a New Version of MAILTOOL and Now Things Are Acting Different? Check the Command Defaults!
Posted by February 28, 2022
BVSTools >> BVSTools Software Discussion >> Email Tools (MAILTOOL) Specific Discussion
Using MAILTOOL Plus on V7R1, or Any OS Using TLS 1.1 or Older Using MAILTOOL Plus on V7R1, or Any OS Using TLS 1.1 or Older
Posted by January 27, 2022
BVSTools >> BVSTools Software Discussion >> Email Tools (MAILTOOL) Specific Discussion
BVSTools ILE Functions Being Updated to Remove Hashtag (#) from Function Names BVSTools ILE Functions Being Updated to Remove Hashtag (#) from Function Names
Posted by December 30, 2021
BVSTools >> BVSTools Announcements

Reply




Copyright 1983-2020 BVSTools
GreenBoard(v3) Powered by the eRPG SDK, MAILTOOL Plus!, GreenTools for Google Apps, jQuery, jQuery UI, BlockUI, CKEditor and running on the IBM i (AKA AS/400, iSeries, System i).